5. Описание системы команд микропроцессоров Intel

Материал, приведенный в данном разделе , связан с уроком 6, на котором мы рассматривали формат машинной команды микропроцессора и систему его команд в целом.

Выберите тему:

Знакомство с порядком описания команд и принятыми обозначениями
Описание команд микропроцессора, упорядоченное по алфавиту
Описание команд микропроцессора, упорядоченное по функциональному признаку
 
 
 
 

Порядок описания команд будет следующим:

• название команды с расшифровкой ее мнемонического обозначения — это облегчит процесс запоминания и последующего использования команды в соответствии с ее функциональным назначением;
• синтаксическое описание команды, поясняющее возможные сочетания операндов для данной команды. При этом сложные синтаксические описания будут приведены в виде синтаксических диаграмм, что позволит в наиболее компактной форме изобразить все возможные сочетания операндов;
• состояние флагов после выполнения команды;
• описание типового применения команды с примером и (или) ссылка на урок, в котором демонстрируется пример применения команды;
• номера занятий и приложений, а также список команд, которые функционально связаны с данной командой.

Для описания команд приняты обозначения:

1. Для описания состояния флагов после выполнения некоторой команды будем использовать выборку из таблицы, отражающей структуру регистра флагов eflags:

В нижней строке этой таблицы приводятся значения флагов после выполнения команды. При этом используются следующие обозначения:

• 1 — после выполнения команды флаг устанавливается (равен 1);
• 0 — после выполнения команды флаг сбрасывается (равен 0);
• r — значение флага зависит от результата работы команды;
• ? — после выполнения команды флаг не определен;
• пробел — после выполнения команды флаг не изменяется;
1. Для представления операндов в синтаксических диаграммах используются следующие обозначения:
• r8, r16, r32 — операнд в одном из регистров размером байт, слово или двойное слово;
• m8, m16, m32, m48 — операнд в памяти размером байт, слово, двойное слово или 48 бит;
• i8, i16, i32 — непосредственный операнд размером байт, слово или двойное слово;
• a8, a16, a32 — относительный адрес (смещение) в сегменте кода.
2. На многих диаграммах в целях компактности возможные сочетания операндов показаны в виде следующей конструкции:

Конструируя команду на основе подобной синтаксической диаграммы, вы должны помнить о соответствии типов. В подобной диаграмме допустимы только следующие сочетания: "r8, m8", "r16, m16", "r32, m32". Например, сочетание "r8, m16" недопустимо. Однако есть единичные случаи, когда подобные сочетания возможны; тогда они специально оговариваются.

4. Описанная в данном приложении система команд в полном объеме поддерживается микропроцессором Pentium. Предыдущие модели микропроцессора могут не поддерживать отдельные команды. Чтобы прояснить этот момент, мы будем указывать в примерах для каждой команды директиву типа .286. Это будет означать, что описываемая команда поддерживается всеми моделями микропроцессора, начиная с i286. Если ничего не указывается, то это означает, что данная команда работает на всех моделях микропроцессоров Intel, начиная с i8086/8088.

AAA

(Ascii Adjust after Addition)

ASCII-коррекция после сложения

Назначение: корректировка неупакованного результата сложения двух одноразрядных неупакованных BCD-чисел.

Синтаксис
Алгоритм работы:

• проанализировать значение младшего полубайта регистра al и значение флага af;
• если (значение младшего полубайта регистра al >9) или (AF=1), то выполнить следующие действия:
• увеличить значение al на 6;
• очистить старший полубайт регистра al;
• увеличить значение ah на 1;
• установить флаги: af = 1, cf = 1,

иначе сбросить флаги af = 0 и cf = 0.

Состояние флагов после выполнения команды:

Применение:
Обычно команда aaa используется после сложения каждого разряда распакованных BCD-чисел командой add. Каждая цифра неупакованного BCD-числа занимает младший полубайт байта. Если результат сложения двух одноразрядных BCD-чисел больше 9, то число в младшем полубайте результата не есть BCD-число. Поэтому результат нужно корректировать командой aaa. Эта команда позволяет сформировать правильное BCD-число в младшем полубайте и запомнить единицу переноса в старший разряд путем увеличения содержимого регистра ah на 1.
К примеру, сложить два неупакованных BCD-числа: 08 + 05:

        mov     ah,08h  ;ah=08h

        mov     al,05h  ;al=05h

        add     al,ah   ;al=al+ah=05h+08h=0dh — не BCD-число

        xor     ah,ah   ;ah=0

        aaa             ;ah=01h,al=03h — результат скорректирован

См. также: урок 8, приложение 7 и команды aad, aam, aas, daa, das

AAD

(Ascii Adjust before Division)

ASCII-коррекция перед делением

Назначение:

• подготовкa двух неупакованных BCD-чисел для операции деления;
• преобразование двузначного неупакованного ВCD-числа меньшего 63h (99₁₀) в двоичное представление.

Синтаксис
Алгоритм работы:

• умножить значение регистра ah на 10 и сложить полученное значение с содержимым регистра al: (ah*10)+al;
• присвоить регистру al значение (ah*10)+al;
• обнулить регистр ah.

Состояние флагов после выполнения команды:

Применение:
Команду aad используют для подготовки двузначного неупакованного BCD-числа в регистре ax для операции деления. Так как в системе команд микропроцессора нет команды деления для BCD-чисел, такое число нужно предварительно преобразовать в двоичный вид. Для этого старший разряд двузначного BCD-числа помещается в регистр ah, умножается на 10 и складывается с разрядом единиц двузначного BCD-числа 9 в регистре al. В результате этих действий и получается соответствующее двоичное число в регистре ax. Далее в программе уже можно применять обычную команду деления div, оперирующую двоичными данными. Команду aad можно применять и просто для преобразования неупакованного двузначного BCD-числа в его двоичный эквивалент. Есть еще интересный момент — если посмотреть на коды символов шестнадцатеричных цифр в таблице ASCII, то видно, что они похожи на BCD-числа. Исключение составляет лишь значение старшей тетрады (для BCD-числа это так называемая зона с нулевым значением) - оно равно 3. Можно сделать вывод, что если предварительно обнулить значение старшей тетрады для кодов двух символов (от 0 до 9), то эту команду вполне можно применять и для преобразования двузначных десятичных чисел в символьном представлении в их двоичный эквивалент, что и отражено в названии команды. Для иллюстрации рассмотрим два примера.

Пример 1. Разделить десятичное число 18 на 9. Подготовить результат к выводу на экран.

        mov     ah,01h  ;ah=01h

        mov     al,08h  ;al=08h => ax=0108h

        mov     bl,09   ;bl=09h

        aаd             ;al=12h — двоичный эквивалент десятичного числа 18

        div     bl      ;al=02h,ah=00h

        ог      al,30h  ;al=32h — ASCII-представление числа 2, можно выводить на экран

Пример 2. Преобразовать десятичное число 16 в символьном виде в эквивалентное двоичное число.

        mov     ax,3136h        ;ax=3136h

        and     ax,0f0fh        ;ax=0106h

        aаd             ;al=10h — получили его двоичный эквивалент

См. также: уроки 3, 8, приложение 7 и команды aaa, aam, aas, daa, das

AAM

(Ascii Adjust after Multiply)

ASCII-коррекция после умножения

Назначение:

• корректировка результата умножения двух неупакованных BCD-чисел;
• преобразование двоичного числа меньшего 63h (99₁₀) в его неупакованный BCD-эквивалент.

Синтаксис
Алгоритм работы:

• разделить значение регистра al на 10;
• записать частное в регистр ah, остаток — в регистр al.

Состояние флагов после выполнения команды:

Применение:
Команду aam используют для коррекции результата умножения двух неупакованных BCD-чисел. Специальной команды умножения BCD-чисел нет. Поэтому BCD-числа умножаются поразрядно, как обычные двоичные числа, командой mul. Максимальное число, которое получается при таком умножении, — это 9*9=81₁₀=51₁₆. Отсюда понятно, что значения, для которых командой aam можно получить их двузначный BCD-эквивалент в регистре ax, находятся в дипазоне от 00h до 51h. Эту команду можно применять и для преобразования двоичного числа из регистра ax (в диапазоне от 0 до 63h) в его десятичный эквивалент(соответственно, из диапазона от 0 до 99₁₀).

Пример 1. Умножить десятичное число 8 на 9. Подготовить результат к выводу на экран.

        mov     ah,08h  ;ah=08h

        mov     al,09h  ;al= 09h

        mul     ah      ;al=48h — двоичный эквивалент 72

        aam             ;ah=07h,al=02h

        or      ax,3030h        ;ax=3732h — ASCII-представление числа 72

Пример 2. Преобразовать двоичное число 60h в эквивалентное десятичное число.

;поместим число 60h в регистр ax

        mov     ax,60h  ;ax=60h

        aаm             ;ax=0906h — получили десятичный эквивалент числа 60h

        or      ax,3030h        ;символьный эквивалент, можно выводить на экран

См. также: урок 8, приложение 7 и команды aaa, aad, aas, daa, das

AAS

(Ascii Adjust after Substraction)

ASCII-коррекция после вычитания

Назначение: корректировка результата вычитания двух неупакованных одноразрядных BCD-чисел.

Синтаксис
Алгоритм работы:
если (младший полубайт регистра al меньше 9) или (флаг af=1), то выполнить следующие действия:

• уменьшить значение младшего полубайта регистра al на 6;
• обнулить значение старшего полубайта регистра al;
• установить флаги af и cf в 1;

иначе установить флаги af и cf в 1.

Состояние флагов после выполнения команды:

Применение:
Команду aas используют для коррекции результата вычитания двух неупакованных одноразрядных BCD-чисел после команды sub. Операндами в команде sub должны быть правильные одноразрядные BCD-числа. Рассмотрим возможные варианты вычитания одноразрядных BCD-чисел:

• 5-9 — для вычитания необходимо сделать заем в старшем разряде. Факт такого заема в микропроцессоре фиксируется установкой флагов cf и af в 1 и вычитанием 1 из содержимого ah. В результате после команды aas в регистре al получается правильное значение (модуль результата), которое для нашего примера (с учетом заема из старшего разряда) составляет 6. Одновременно моделируется заем из старшего разряда, что позволяет производить вычитание длинных чисел.
• 8-6 — для вычитания нет необходимости делать заем в старшем разряде. Поэтому производится сброс флагов cf и af в 0, а ah не изменяется. В результате после команды aas в регистре al получается правильное значение (модуль результата), которое для нашего примера составляет 2.

Пример 1. Вычесть десятичное число 8 из 5. Подготовить результат к выводу на экран.

        mov     al,05h

        mov     bl,08h

        sub     al,bl   ;al=0fdh

        aas             ;al=07, cf=af=1

        or      al,30h  ;al=37h — код символа 7

;вывод результата на экран

        mov     ah,2

        mov     dl,al

        int     21h

См. также: уроки 3, 8, приложение 7 и команды aaa, aad, aam, daa, das

ADC

(Addition with Carry)

Сложение с переносом

Назначение: сложение двух операндов с учетом переноса из младшего разряда.

Синтаксис
Алгоритм работы:

• сложить два операнда;
• поместить результат в первый операнд: приемник=приемник+источник;
• в зависимости от результата установить флаги.

Состояние флагов после выполнения команды:

Применение:
Команда adc используется при сложении длинных двоичных чисел. Ее можно использовать как самостоятельно, так и совместно с командой add. При совместном использовании команды adc с командой add сложение младших байтов/слов/двойных слов осуществляется командой add, а уже старшие байты/слова/двойные слова складываются командой adc, учитывающей переносы из младших разрядов в старшие. Таким образом, команда adc значительно расширяет диапазон значений складываемых чисел. В приложении 7 приведен пример программы сложения двоичных чисел произвольной размерности.

.data

sl1     dd      01fe544fh

sl2     dd      005044cdh

elderREZ        db      0 ;для учета переноса из старшего разряда результата

rez     dd      0

.code

...

        mov     ax,sl1

        add     ax,sl2  ;сложение младших слов слагаемых

        mov     rez,ax

        mov     ax,sl+2

        adc     ax,sl2+2        ;сложение старших слов слагаемых плюс cf

        mov     rez+2,ax

        adc     elderREZ,0      ;учесть возможный перенос

См. также: урок 8, приложение 7 и команды add, sub, sbb, xadd

ADD

(ADDition)

Сложение

Назначение: сложение двух операндов источник и приемник размерностью байт, слово или двойное слово.

Синтаксис
Алгоритм работы:

• сложить операнды источник и приемник;
• записать результат сложения в приемник;
• установить флаги.

Состояние флагов после выполнения команды:

Применение:
Команда add используется для сложения двух целочисленных операндов. Результат сложения помещается по адресу первого операнда. Если результат сложения выходит за границы операнда приемник (возникает переполнение), то учесть эту ситуацию следует путем анализа флага cf и последующего возможного применения команды adc. Например, сложим значения в регистре ax и области памяти ch. При сложении следует учесть возможность переполнения.

chiclo  dw      2015

rez     dd      0

...

        add     ax,chislo       ;(ax)=(ax)+ch

        mov     word ptr rez,ax

        jnc     dop_sum         ;переход, если результат не вышел за разрядную сетку

        adc     word ptr rez+2,0        ;расширить результат, для учета переноса

                                ;в старший разряд

dop_sum:

...

См. также: урок 8, Приложение 7 и команды adc, sub, sbb, xadd

AND

(logical AND)

Логическое И

Назначение: операция логического умножения для операндов приемник и источник размерностью байт, слово или двойное слово.

Синтаксис
Алгоритм работы:

• выполнить операцию логического умножения над операндами источник и приемник: каждый бит результата равен 1, если соответствующие биты операндов равны 1, в остальных случаях бит результата равен 0;
• записать результат операции в приемник;
• установить флаги.

Состояние флагов после выполнения команды:

Применение:
Команда and используется для логического умножения двух операндов. Результат операции помещается по адресу первого операнда. Эту команду удобно использовать для принудительной установки или сброса определенных битов операнда.
Например, преобразуем двузначное упакованное BCD-число в его символьный эквивалент.

u_BCD   db      25h ;упакованное BCD-число

s_ch    dw      0 ;место для результата

...

        xor     ax,ax   ;очистка ax

        mov     al,u_BCD

        shl     ax,4    ;ax=0250

        mov     al,u_BCD        ;ax=0225

;преобразование в символьное представление:

        and     ax,3f3fh        ;ax=3235h

        mov     s_ch,ax

См. также: уроки 9, 12 и команды or, xor, test

BOUND

(check array BOUNDs)

Контроль нахождения индекса массива в границах

Назначение: проверка нахождения значения индекса в границах массива.

Синтаксис
Алгоритм работы:
Cравнить значение в регистре индекс с двумя значениями, расположенными последовательно в ячейке памяти, адресуемой операндом границы массива. Диапазон значений индекса определяется используемым регистром индекс:

• если это 16-разрядный регистр общего назначения, то содержащееся в нем значение проверяется на попадание в диапазон значений, которые находятся в двух последовательных словах в памяти по адресу, указываемому вторым операндом. Эти два значения являются, соответственно, значениями нижнего и верхнего индекса границы массива;
• если это 32-разрядный регистр общего назначения, то содержащееся в нем значение проверяется на попадание в диапазон значений, которые находятся в двух последовательных двойных словах в памяти по адресу, указываемому вторым операндом. Эти два значения являются, соответственно, значениями нижнего и верхнего индекса границы массива;

Если в результате проверки значение из регистра вышло за пределы указанного диапазона значений, то возбуждается прерывание с номером 5, если нет, программа продолжает выполнение.

Состояние флагов после выполнения команды:

Применение:
Команду bound очень удобно использовать для контроля выхода за нижнюю или верхнюю границы массива. Значения этих границ должны быть предварительно помещены в два последовательных слова (двойных слова) в памяти. Адрес этих слов (двойных слов) указывается вторым операндом. Далее динамически в ходе работы программы значение в регистре индекс, указываемом первым операндом, сравнивается со значениями этих двух границ, и если нижняя_граница<=(индексindex)<=верхняя_граница, то программа продолжает выполнение. В противном случае генерируется исключительная ситуация 5 (int 5). Далее в программе обработки этой ситуации можно выполнить необходимую корректировку и вернуться в программу (см. урок 17).

Фрагмент, который можно использовать при обработке одномерного массива с размерностью элементов в слово:

.286    ;это обязательная директива, так как bound

        ;входит в систему команд микропроцессоров, начиная с i286

.data

BoundMas        label   word

Low_Bound       dw      0

Upp_Bound       dw      20

mas     dw      10 dup (?)

...

        xor     di,di   ;очистка индексного регистра

cycl:

        mov     ax,mas[di]      ;перебор

элементов массива

        add     di,2

        bound   di,BoundMas

;если значение в di не будет попадать в границы, то будет вызван

;обработчик прерывания 5, где можно скорректировать

;значение ip/eip в стеке с тем, чтобы выйти

;из бесконечного ;цикла, например, на метку М2 или

;выполнить другие действия

        jmp     cycl

М2:

...

См. также: урок 17 и команду iret/iretd

BSF

(Bit Scan Forward)

Побитное сканирование вперед

Назначение: для проверки наличия единичных битов в операнде источник.

Синтаксис
Алгоритм работы:

• просмотр битов операнда источник, начиная с бита 0 и заканчивая битом 15/31, до тех пор, пока не встретится единичный бит;
• если встретился единичный бит, то флаг zf устанавливается в 0 и в регистр первого операнда записывается номер позиции, где встретился единичный бит. Диапазон значений зависит от разрядности второго операнда: для 16-разрядного операнда — это 0...15; для 32-разрядного — это 0...31;
• если единичных битов нет, то флаг zf устанавливается в 1.

Состояние флагов после выполнения команды:

Применение:
Команду bsf используют при работе на битном уровне для определения позиции в операнде крайних справа единичных битов.
Например, сдвинем содержимое регистра bx вправо таким образом, чтобы нулевой бит стал единичным:

.386

        mov     bx,0002h        ;bx=0000 0010b

...

        bsf     cx,bx   ;cx=0001h

        jz      null

        shr     bx,cl   ;bx=0000 0001b

...

null:

См. также: урок 9, 12 и команду bsr

BSR

(Bit Scan Reverse)

Побитное сканирование назад

Назначение: проверка наличия единичных битов в операнде источник.

Синтаксис
Алгоритм работы:

• просмотр битов операнда источник, начиная со старшего бита 15/31 и заканчивая битом 0, до тех пор, пока не встретится единичный бит;
• если встретился единичный бит, флаг zf устанавливается в 0 и в регистр первого операнда записывается номер позиции (отсчет осуществляется относительно нулевой позиции), где встретился самый старший единичный бит. Диапазон значений зависит от разрядности второго операнда: для 16-разрядного операнда это 0...15; для 32-разрядного — 0...31;
• если единичных битов нет, флаг zf устанавливается в 1.

Состояние флагов после выполнения команды:

Применение:
Команду bsr используют при работе на битном уровне для определения позиции крайних слева единичных битов.

Например, сдвинем содержимое регистра bx вправо таким образом, чтобы старший единичный бит исходного значения в bx переместился в нулевую позицию:

.386

        mov     bx,41h

...

        bsr     cx,bx   ;cx=06h

        jz      null

        shr     bx,ax   ;bx=0001h

...

null:...

См. также: уроки 9, 12 и команду bsf

BSWAP

(Byte SWAP)

Перестановка байтов

Назначение:

• изменение порядка следования байтов;
• переход от одной формы адресации к другой.

Под формой адресации здесь понимается принцип "младший байт по младшему адресу" или обратный ему. Существует ряд систем, например использующих микропроцессоры Motorola или большие ЭВМ, где применяется принцип размещения многобайтовых значений обратный тому, который используется в микропроцессорах Intel. Поэтому эту команду можно использовать для разработки программ-конверторов между подобными платформами и IBM РС.

Синтаксис
Алгоритм работы: Схема алгоритма
Состояние флагов после выполнения команды:

Применение:
Команду bswap используют для изменения формы адресации. В качестве операнда может быть указан только 32-разрядный регистр. Эта команда используется в моделях микропроцессоров, начиная с i486.

.486

        mov     ebx,1a2c345fhh

        bswap   ebx     ;ebx=5f342c1ah

См. также: урок 7, и команду xchg

BT

(Bit Test)

Проверка битов

Назначение: извлечение значения заданного бита в флаг cf.

Синтаксис
Алгоритм работы:

• получить бит по указанному номеру позиции в операнде источник;
• установить флаг cf согласно значению этого бита.

Состояние флагов после выполнения команды:

Применение:
Команду bt используют для определения значения конкретного бита в операнде источник. Номер проверяемого бита задается содержимым второго операнда (значение числом из диапазона 0...31). После выполнения команды, флаг cf устанавливается в соответствии со значением проверяемого бита.

.386

        mov     ebx,01001100h

        bt      ebx,8   ;проверка состояния бита 8 и установка cf= в 1

        jc      m1      ;перейти на m1, если проверяемый бит равен 1

...

См. также: уроки 9, 12 и команды btc, btr, bts, test

BTC

(Bit Test and Complement)

Проверка бита с инверсией (дополнением)

Назначение: извлечение значения заданного бита в флаг cf и изменение его значения в операнде на обратное.

Синтаксис
Алгоритм работы:

• получить значение бита с номером позиции индекс в операнде источник;
• инвертировать значение выбранного бита в операнде источник;
• установить флаг сf исходным значением бита.

Состояние флагов после выполнения команды:

Применение:
Команда btс используется для определения и инвертирования значения конкретного бита в операнде источник. Номер проверяемого бита задается содержимым второго операнда индекс (значение из диапазона 0...31). После выполнения команды флаг cf устанавливается в соответствии с исходным значением бита, то есть тем, которое было до выполнения команды.

.386

        mov     ebx,01001100h

;проверка состояния бита 8 и его обращение:

        btc     ebx,8   ;cf=1 и ebx=01001000h

См. также: уроки 9, 12 и команды bt, btr, bts, test

BTR

(Bit Test and Reset)

Проверка бита с его сбросом в 0

Назначение: извлечение значения заданного бита в флаг cf и изменение его значения на нулевое.

Синтаксис
Алгоритм работы:

• получить значение бита с указанным номером позиции в операнде источник;
• установить флаг cf значением выбранного бита;
• установить значение исходного бита в операнде в 0.

Состояние флагов после выполнения команды:

Применение:
Команда btr используется для определения значения конкретного бита в операнде источник и его сброса в 0. Номер проверяемого бита задается содержимым второго операнда индекс (значение из диапазона 0...31). В результате выполнения команды флаг cf устанавливается в соответствии со значением исходного бита, то есть тем, что было до выполнения операции.

.386

        mov     ebx,01001100h

;проверка состояния бита 8 и его сброс в 0

        btr     ebx,8   ;cf=1 и ebx=01001000h

См. также: уроки 9, 12 и команды bt, btc, bts, test

BTS

(Bit Test and Set)

Проверка бита с его установкой в 1

Назначение: извлечение значения заданного бита операнда в флаг cf и установка этого бита в единицу.

Синтаксис
Алгоритм работы:

• получить значение бита с указанным номером позиции в операнде источник;
• установить флаг cf значением выбранного бита;
• установить значение исходного бита в операнде источник в 1.

Состояние флагов после выполнения команды:

Применение:
Команда bts используется для определения значения конкретного бита в операнде источник и установки проверяемого бита в 1. Номер проверяемого бита задается содержимым второго операнда индекс (значение из диапазона 0...31). После выполнения команды флаг cf устанавливается в соответствии со значением исходного бита, то есть тем, что было до выполнения операции.

.386

        mov     ebx,01001100h

;проверка состояния бита 0 и его установка в 1

        bts     ebx,0   ;cf=0 ebx=01001001h

См. также: уроки 9, 12 и команды bt, btc, btr, test

CALL

(CALL)

Вызов процедуры или задачи

Назначение:

• передача управления близкой или дальней процедуре с запоминанием в стеке адреса точки возврата;
• переключение задач.

Синтаксис
Алгоритм работы:
определяется типом операнда:

• метка ближняя — в стек заносится содержимое указателя команд eip/ip и в этот же регистр загружается новое значение адреса, соответствующее метке;
• метка дальняя — в стек заносится содержимое указателя команд eip/ip и cs. Затем в эти же регистры загружаются новые значения адресов, соответствующие дальней метке;
• r16, 32 или m16, 32 — определяют регистр или ячейку памяти, содержащие смещения в текущем сегменте команд, куда передается управление. При передаче управления в стек заносится содержимое указателя команд eip/ip;
• указатель на память — определяет ячейку памяти, содержащую 4 или 6-байтный указатель на вызываемую процедуру. Структура такого указателя 2+2 или 2+4 байта. Интерпретация такого указателя зависит от режима работы микропроцессора:
• в реальном режиме — в зависимости от размера адреса (use16 или use32) первые два байта трактуются как сегментный адрес, вторые два/четыре байта, как смещение целевой метки передачи управления. В стеке запоминается содержимое регистров cs и eip/ip;
• в защищенном режиме — интерпретация цели передачи управления зависит от значения байта AR дескриптора, определяемого селекторной частью указателя. Целью здесь являются дальний вызов процедуры без изменения уровня привилегий, дальний вызов процедуры с изменением уровня привилегий или переключение задачи.

Состояние флагов после выполнения команды (кроме переключения задачи):

При переключении задачи значения флажков изменяются в соответствии с информацией о регистре eflags в сегменте состояния TSS задачи, на которую производится переключение.
Применение:
Как видно из описания алгоритма, команда call позволяет организовать гибкую и многовариантную передачу управления на подпрограмму с сохранением адреса точки возврата. Подробно типовые примеры использования рассмотрены на уроках 10 и 14.
См. также: уроки 10, 14 и команду ret

CBW/CWDE

(Convert Byte to Word/Convert Word to Double Word Extended)

Преобразование байта в слово/слова в двойное слово

Назначение: расширение операнда со знаком.

Синтаксис
Алгоритм работы:
cbw — при работе команда использует только регистры al и ax:

• анализ знакового бита регистра al:
• если знаковый бит al=0, то ah=00h;
• если знаковый бит al=1, то ah=0ffh.

cwde — при работе команда использует только регистры ax и eax:

• анализ знакового бита регистра ax:
• если знаковый бит ax=0, то установить старшее слово eax=0000h;
• если знаковый бит ax=1, то установить старшее слово eax=0ffffh.

Состояние флагов после выполнения команды:

Применение:
Данные команды используются для приведения операндов к нужной размерности с учетом знака. Такая необходимость может, в частности, возникнуть при программировании арифметических операций.

.386    ;только для cwde, cwd была для i8086

        mov     ebx,10fecd23h

        mov     ax,-3   ;ax=1111 1111 1111 1101

        cwde    ;eax=1111 1111 1111 1111 1111 1111 1111 1101

        add     eax,ebx

См. также: урок 8 и команды cdq, cwd

CLC

(CLear Carry flag)

Сброс флага переноса

Назначение: сброс флага переноса cf.

Синтаксис
Алгоритм работы:
установка флага cf в ноль.
Состояние флагов после выполнения команды:

Применение:
Данная команда используется для сброса флага cf в ноль. Такая необходимость может возникнуть при работе с командами сдвига, арифметическими командами либо действиями по индикации обнаружения ошибок и различных ситуаций в программе.

        clc             ;cf=0

См. также: уроки 8, 9 и команды cmc, stc

CLD

(CLear Direction flag)

Сброс флага направления

Назначение: сброс в ноль флага направления df.

Синтаксис
Алгоритм работы:
установка флага df в ноль.
Состояние флагов после выполнения команды:

Применение:
Данная команда используется для сброса флага df в ноль. Такая необходимость может возникнуть при работе с цепочечными командами. Нулевое занчение флага df вынуждает микропроцессор при выполнении цепочечных операций производить инкремент регистров si и di.

        cld             ;df=0

См. также: урок 11 и команды stc, movs/movsb/movsw/movsd,
cmps/cmpsb/cmpsw/cmpsd, scas/scasb/scasw/scasd,
lods/lodsb/lodsw/lodsd, stos/stosb/stosw/stosd,
ins/insb/insw/insd, outs

CLI

(CLear Interrupt flag)

Сброс флага прерывания

Назначение: сброс флага прерывания if.

Синтаксис
Алгоритм работы:
установка флага if в ноль.
Состояние флагов после выполнения команды:

Применение:
Данная команда используется для сброса флага if в ноль. Такая необходимость может возникнуть при разработке программ обработки прерываний.

        cli             ;if=0

См. также: урок 15 и команды int, iret/iretd, sti

CMC

(CoMplement Carry flag)

Инвертирование флага переноса

Назначение: изменение значения флага переноса cf на обратное.

Синтаксис
Алгоритм работы:
инвертирование значения флага переноса cf.
Состояние флагов после выполнения команды:

Применение:
Данная команда используется для изменения значения флага cf на противоположное. В частности, этот флаг можно использовать для связи с процедурой и по его состоянию судить о результате работы данной процедуры. После выхода из процедуры этот флаг можно проанализировать командой условного перехода jc.

proc1   proc

...

        cmc

...

proc1   endp

...

        call    proc1

        jc      m1      ;если cf=1, то переход на m1

...

m1:

...

См. также: уроки 8, 9, 15 и команды clc, stc, jc, jnc

CMP

(CoMPare operands)

Сравнение операндов

Назначение: сравнение двух операндов.

Синтаксис
Алгоритм работы:

• выполнить вычитание (операнд1-операнд2);
• в зависимости от результата установить флаги, операнд1 и операнд2 не изменять (то есть результат не запоминать).

Состояние флагов после выполнения команды:

Применение:
Данная команда используется для сравнения двух операндов методом вычитания, при этом операнды не изменяются. По результатам выполнения команды устанавливаются флаги. Команда cmp применяется с командами условного перехода и командой установки байта по значению setcc.

len     equ     10

...

        cmp     ax,len

        jne     m1      ;переход если (ax)<>len

        jmp     m2      ;переход если (ax)=len

См. также: уроки 10, 11, 12 и команды cmps/cmpsb/cmpsw/cmpsd, cmpxchg, sub, jcc, setcc

CMPS/CMPSB/CMPSW/CMPSD

(CoMPare String Byte/Word/Double word operands)

Сравнение строк байтов/слов/двойных слов

Назначение: сравнение двух последовательностей (цепочек) элементов в памяти.

Синтаксис
Алгоритм работы:

• выполнить вычитание элементов (источник - приемник), адреса элементов предварительно должны быть загружены:
• адрес источника — в пару регистров ds:esi/si;
• адрес назначения — в пару регистров es:edi/di;
• в зависимости от состояния флага df изменить значение регистров esi/si и edi/di:
• если df=0, то увеличить содержимое этих регистров на длину элемента последовательности;
• если df=1, то уменьшить содержимое этих регистров на длину элемента последовательности;
• в зависимости от результата вычитания установить флаги:
• если очередные элементы цепочек не равны, то cf=1, zf=0;
• если очередные элементы цепочек или цепочки в целом равны, то cf=0, zf=1;
• при наличии префикса выполнить определяемые им действия (см. команды repe/repne).

Состояние флагов после выполнения команды:

Применение:
Команды без префиксов осуществляют простое сравнение двух элементов в памяти. Размеры сравниваемых элементов зависят от применяемой команды. Команда cmps может работать с элементами размером в байт, слово, двойное слово. В качестве операндов в команде указываются идентификаторы последовательностей этих элементов в памяти. Реально эти идентификаторы используются лишь для получения типов элементов последовательностей, а их адреса должны быть предварительно загружены в указанные выше пары регистров. Транслятор, обработав команду cmps и выяснив тип операндов, генерирует одну из машинных команд cmpsb, cmpsw или cmpsd. Машинного аналога для команды cmps нет. Для адресации назначения обязательно должен использоваться регистр es, а для адресации источника можно делать замену сегмента с использованием соответствующего префикса.
Для того чтобы эти команды можно было использовать для сравнения последовательности элементов, имеющих размерность байт, слово, двойное слово, необходимо использовать один из префиксов repe или repne. Префикс repe заставляет циклически выполняться команды сравнения до тех пор, пока содержимое регистра ecx/cx не станет равным нулю или пока не совпадут очередные сравниваемые элементы цепочек (флаг zf=1). Префикс repne заставляет циклически производить сравнение до тех пор, пока не будет достигнут конец цепочки (ecx/cx=0) либо не встретятся различающиеся элементы цепочек (флаг zf=0).

.data

obl1    db      'Строка для сравнения'

obl1    db      'Строка для сравнения'

a_obl1  dd      obl1

a_obl2  dd      obl2

.code

...

        cld             ;просмотр цепочки в направлении возрастания адресов

        mov     cx,20   ;длина цепочки

        lds     si,a_obl1       ;адрес источника в пару ds:si

        les     di,a_obl2       ;адрес назначения в пару ds:si

repe    cmpsb           ;сравнивать, пока равны

        jnz     m1      ;если не конец цепочки, то встретились разные элементы

...                     ;действия, если цепочки совпали

...

m1:

...                     ;действия, если цепочки не совпали

См. также: уроки 10, 11 и команды ins, lods, movs, outs, scas, stos, repe, repz, repne, repnz

CMPXCHG

(CoMPare and eXCHanGe)

Сравнение и обмен

Назначение: сравнение и обмен значений между источником и приемником.

Синтаксис
Алгоритм работы:

• выполнить сравнение элементов источник и приемник;
• если источник и приемник не равны, то:
• установить zf=0;
• переслать содержимое операнда приемник в источник (регистр al/ax/eax).
• если источник и приемник равны, то:
• установить zf=1;
• переслать содержимое операнда источник (регистр al/ax/eax) по месту операнда приемник.

Состояние флагов после выполнения команды:

Применение:
Команды сравнивают два операнда. Один из сравниваемых операндов находится в аккумуляторе (регистре al/ax/eax), другой может находиться в памяти или регистре общего назначения. Если значения равны, то производится замена содержимого операнда приемник содержимым источника, находящимся в регистре-аккумуляторе. Если значения не равны, то производится замена содержимого операнда источника находящимся в регистре-аккумуляторе содержимым операнда назначения. Определить тот факт, была ли произведена смена значения в аккумуляторе (то есть были ли не равны сравниваемые операнды), можно по значению флага zf.

.486

        mov     ax,114eh

        mov     bx,8e70h

        cmpxchg bx,ax

        jz      m1      ;переход, если zf=1, то есть операнды равны

                        ;и ax не изменился

...                     ;действия, если операнды не равны

m1:

См. также: уроки 7, 10 и команды cmp, xchg

CWD

(Convert Word to Double word)

Преобразование слова в двойное слово

Назначение: расширение слова со знаком до размера двойного слова со знаком.

Синтаксис
Алгоритм работы:
копирование значения старшего бита регистра ax во все биты регистра dx. Состояние флагов после выполнения команды:

Применение:
Команда cwd используется для расширения значения знакового бита в регистре ax на биты регистра dx. Данную операцию, в частности, можно использовать для подготовки к операции деления, для которой размер делимого должен быть в два раза больше размера делителя, либо для приведения операндов к одной размерности в командах умножения, сложения, вычитания.

        mov     ax,25

...

        mov     bx,4

        cwd

        div     bx

См. также: урок 8 и команды cbw, cdq, cwde, div, idiv, mul, imul, add, adc, sub, sbb

CDQ

(Convert Double word to Quad word)

Преобразование двойного слова в учетверенное слово

Назначение: расширение двойного слова со знаком до размера учетверенного слова (64 бита) со знаком.

Синтаксис
Алгоритм работы:
копирование значения старшего бита регистра eax на все биты регистра edx. Состояние флагов после выполнения команды:

Применение:
Команду cdq можно использовать для распространения значения знакового бита в регистре eax на все биты регистра edx. Данную операцию, в частности, можно использовать для подготовки к операции деления, для которой размер делимого должен быть в два раза больше размера делителя.

.386

delimoe dd      ...

delitel dd      ...

...

        mov     eax,delimoe

        cdq

        idiv    delitel ;частное в eax, остаток в edx

См. также: урок 8 и команды cbw, cwd, cwde, div, idiv

DAA

(Decimal Adjust for Addition)

Десятичная коррекция после сложения

Назначение: коррекция упакованного результата сложения двух BCD-чисел в упакованном формате.

Синтаксис
Алгоритм работы:
команда работает только с регистром al и анализирует наличие следующих ситуаций:

• Ситуация 1. В результате предыдущей команды сложения флаг af=1 или значение младшей тетрады регистра al>9. Напомним, что флаг af устанавливается в 1 в случае переноса двоичной единицы из бита 3 младшей тетрады в старшую тетраду регистра al (если значение превысило 0fh). Наличие одного из этих двух признаков говорит о том, что значение младшей тетрады превысило 9h.
• Ситуация 2. В результате предыдущей команды сложения флаг сf=1 или значение регистра al>9fh. Напомним, что флаг cf устанавливается в 1 в случае переноса двоичной единицы в старший бит операнда (если значение превысило 0ffh в случае регистра al). Наличие одного из этих двух признаков говорит о том, что значение в регистре al превысило 9fh.

Если имеет место одна из этих двух ситуаций, то регистр al корректируется следующим образом:

• для ситуации 1 содержимое регистра al увеличивается на 6;
• для ситуации 2 содержимое регистра al увеличивается на 60h;
• если имеют место обе ситуации, то корректировка начинается с младшей тетрады.

Состояние флагов после выполнения команды (в случае, если были переносы):

Состояние флагов после выполнения команды (в случае, если переносов не было):

Применение:
Эту команду следует применять после сложения двух упакованных BCD-чисел с целью корректировки получающегося двоичного результата сложения в правильное двузначное десятичное число. После команды daa следует анализировать состояние флага cf. Если он равен 1, то это говорит о том, что был перенос единицы в старший разряд и это нужно учесть для сложения старших десятичных цифр BCD-числа.

        mov     al,69h  ;69h — упакованное BCD-число

        mov     bl,74h  ;74h — упакованное BCD-число

        adc     al,bl   ;al=0ddh

        daa             ;cf=1, al=43h

;если перенос, то переход на ту ветвь программы,

;где он будет учтен:

        jc m1

См. также: урок 8, Приложение 7 и команды aaa, aad, aam, aas, das

DAS

(Decimal Adjust for Subtraction)

Десятичная коррекция после вычитания

Назначение: коррекция упакованного результата вычитания двух BCD-чисел в упакованном формате.

Синтаксис
Алгоритм работы:
команда das работает только с регистром al и анализирует наличие следующих ситуаций:

• Ситуация 1. В результате предыдущей команды сложения флаг af =1 или значение младшей тетрады регистра al>9. Напомним, что для случая вычитания флаг af устанавливается в 1 в случае заема двоичной единицы из старшей тетрады в младшую тетраду регистра al. Наличие одного из этих двух признаков говорит о том, что значение младшей тетрады превысило 9h и его нужно корректировать.
• Ситуация 2. В результате предыдущей команды сложения флаг сf =1 или значение регистра al>9fh. Напомним, что для случая вычитания флаг cf устанавливается в 1 в случае заема двоичной единицы. Наличие одного из этих двух признаков говорит о том, что значение в регистре al превысило 9fh.

Если имеет место одна из этих ситуаций, то регистр al корректируется следующим образом:

• для ситуации 1 содержимое регистра al уменьшается на 6;
• для ситуации 2 содержимое регистра al уменьшается на 60h;
• если имеют место обе ситуации, то корректировка начинается с младшей тетрады.

Состояние флагов после выполнения команды (в случае, если были переносы):

Состояние флагов после выполнения команды (в случае, если переносов не было):

Применение:
Команду das следует применять после вычитания двух упакованных BCD-чисел с целью корректировки получающегося двоичного результата вычитания в правильное двузначное десятичное число. После команды das следует анализировать состояние флага cf. Если он равен 1, то это говорит о том, что был заем единицы в старший разряд и это нужно учесть в дальнейших действиях. Если у вычитаемого нет больше старших разрядов, то результат следует трактовать как отрицательное двоичное дополнение. Для определения его абсолютного значения нужно вычесть 100 из результата в al. Если у вычитаемого еще есть старшие разряды, то факт заема нужно просто учесть уменьшением младшего из этих оставшихся старших разрядов на единицу.

        mov     ah,08h  ;ah=08h

        mov     al,05h  ;al=05h

        add     al,ah   ;al=al+ah=05h+08h=0dh — не BCD-число

        xor     ah,ah   ;ah=0

        aaa             ;ah=01h,al=03h — результат скорректирован

См. также: урок 8, Приложение 7 и команды aaa, aad, aam, aas, daa

DEC

(DECrement operand by 1)

Уменьшение операнда на единицу

Назначение: уменьшение значения операнда в памяти или регистре на 1.

Синтаксис
Алгоритм работы:
команда вычитает 1 из операнда. Состояние флагов после выполнения команды:

Применение:
Команда dec используется для уменьшения значения байта, слова, двойного слова в памяти или регистре на единицу. При этом заметьте то, что команда не воздействует на флаг cf.

        mov     al,9

...

        dec     al      ;al=8

См. также: урок 8 и команды inc, sub

DIV

(DIVide unsigned)

Деление беззнаковое

Назначение: выполнение операции деления двух двоичных беззнаковых значений.

Синтаксис
Алгоритм работы:
Для команды необходимо задание двух операндов — делимого и делителя. Делимое задается неявно и размер его зависит от размера делителя, который указывается в команде:

• если делитель размером в байт, то делимое должно быть расположено в регистре ax. После операции частное помещается в al, а остаток — в ah;
• если делитель размером в слово, то делимое должно быть расположено в паре регистров dx:ax, причем младшая часть делимого находится в ax. После операции частное помещается в ax, а остаток — в dx;
• если делитель размером в двойное слово, то делимое должно быть расположено в паре регистров edx:eax, причем младшая часть делимого находится в eax. После операции частное помещается в eax, а остаток — в edx.

Состояние флагов после выполнения команды:

Применение:
Команда выполняет целочисленное деление операндов с выдачей результата деления в виде частного и остатка от деления. При выполнении операции деления возможно возникновение исключительной ситуации: 0 — ошибка деления. Эта ситуация возникает в одном из двух случаев: делитель равен 0 или частное слишком велико для его размещения в регистре eax/ax/al.

        mov     ax,10234

        mov     bl,154

        div     bl      ;ah=остаток, al=частное

См. также: урок 8, приложение 7 и команду idiv

ENTER

(setup parameter block for ENTERing procedure)

Установка кадра стека для параметров процедуры

Назначение: установка границы в стеке для локальных переменных процедуры.

Синтаксис
Алгоритм работы:

• поместить текущее значение регистра ebp/bp в стек;
• сохранить текущее значение esp/sp в промежуточной переменной fp (имя переменной выбрано случайно);
• если лексический уровень вложенности (операнд lex_lev) не равен нулю, то (lex_lev–1) раз делать следующее:
• в зависимости от установленного режима адресации use16 или use32 выполнить вычитание (bp–2) или (ebp–4) и записать результат обратно в ebp/bp;
• сохранить значение ebp/bp в стеке;
• сохранить в стеке значение промежуточной переменной fp;
• записать значение промежуточной переменной fp в регистр ebp/bp;
• уменьшить значение регистра esp/sp на величину, заданную первым операндом, минус размер области локальных переменных loc_size: esp/sp=(esp/sp)–loc_size.

Состояние флагов после выполнения команды:

Применение:
Команда enter специально введена в систему команд микропроцессора для поддержки блочно-структурированных языков высокого уровня типа Pascal или С. В этих языках программа разбивается на блоки. В блоках можно описать свои собственные (локальные) идентификаторы, которые не могут быть использованы вне этого блока. К примеру, на рисунке ниже в виде блоков изображена структура некоторой программы.

Изображение структуры некоторой программы в виде блоков

В правом верхнем углу каждого блока (процедуры) стоит номер лексического уровня вложенности этого блока относительно других блоков программы. Большинство блочно-структурированных языков в качестве основного метода распределения памяти для переменных в блоках используют автоматическое распределение памяти. Это означает, что при входе в блок (вызове процедуры и т. п.) в некотором месте памяти (или в стеке) выделяется область памяти для переменных этого блока (ее можно назвать областью инициализации). После выхода из этого блока связь программы с этой областью теряется, то есть эти переменные становятся недоступными. Но если, как в нашем примере, в этой процедуре есть вложенные блоки (процедуры), то для некоторого внутреннего блока (например, C) могут быть доступны области инициализации (переменные) блоков, объемлющих данный блок. В нашем примере для блока C доступны также переменные блоков B и A, но не D. Возникает вопрос: как же программа, находясь в конкретной точке своего выполнения, может отслеживать то, какие области инициализации ей доступны? Это делается с помощью структуры данных, называемой дисплеем. Дисплей содержит указатели на самую последнюю область текущего блока и на области инициализации всех блоков, объемлющих данный блок в программе. Например, если в программе A была вызвана сначала процедура B, а затем C, то дисплей содержит указатели на области инициализации A, B и C (см. рисунок ниже).

Если после этого вызвать процедуру D (в то время как B и C еще не завершены), то картина изменится.

После того как некоторый блок (процедура) завершает свою работу, ее область инициализации удаляется из памяти (стека) и одновременно соответствующим образом корректируется дисплей. Большинство языков высокого уровня хранят локальные данные блоков в стеке. Эти переменные называют еще автоматическими или динамическими. Память для них резервируется путем уменьшения значения регистра-указателя стека esp/sp на величину, равную длине области, занимаемой этими динамическими переменными. Доступ к этим переменным осуществляется посредством регистра ebp/bp. Если один блок вложен в другой, то для его динамических (локальных) переменных также выделяется место (кадр) в стеке, но в этот кадр помещается указатель на кадр стека для включающего его блока. Команды enter и leave как раз и позволяют поддержать в языке ассемблера принципы работы с переменными блоков как в блочно-структурированных языках. Дисплей организуется с помощью второго операнда команды enter и стека. Например, в начале работы главной процедуры A и после вызова процедуры B кадр стека будет выглядеть так.

Соответственно, после вызова процедур C и D стек будет выглядеть, как показано ниже.

Таким образом, видно, что используя дисплей, мы фактически имеем адреса областей инициализации, доступных по признаку вложенности объемлющих блоков. Обратный процесс завершения работы с блоками и удаления соответствующих областей инициализации поддерживается командой leave.

.286

proc1   proc

;зарезервировать в стеке место для локальных переменных

;proc1 16 байт

;лексический уровень вложенности 0

        enter   16,0

...

        leave

        ret

proc1   endp

См. также: урок 14 и команды leave, ret

HLT

(HaLT)

Остановка

Назначение: остановка микропроцессора до прерывания или перезагрузки.

Синтаксис
Алгоритм работы:
перевод микропроцессора в состояние остановки.
Состояние флагов после выполнения команды:

Применение:
В результате выполнения команды микропроцессор переходит в состояние остановки. Из этого состояния его можно вывести сигналами на входах RESET, NMI, INTR. Если для возобновления работы микропроцессора используется прерывание, то сохраненное значение пары cs:eip/ip указывает на команду, следующую за hlt. Для иллюстрации применения данной команды рассмотрим еще один способ переключения микропроцессора из защищенного в реальный режим и его возврата обратно в реальный режим (см. урок 16). Как известно, в микропроцессоре не предусмотрено специальных средств для подобного переключения. Сброс микропроцессора можно инициировать, если вывести байт со значением 0feh в порт клавиатуры 64h. После этого микропроцесор переходит в реальный режим и управление получает программа BIOS, которая анализирует байт отключения в CMOS-памяти по адресу 0fh. Для нас интерес представляют два значения этого байта — 5h и 0ah:

• 5h — сброс микропроцессора инициирует инициализацию программируемого контроллера прерываний на значение базового вектора 08h (см. уроки 15 и 17). Далее управление передается по адресу, который находится в ячейке области данных BIOS 0040:0067;
• 0ah — сброс микропроцессора инициирует непосредственно передачу управления по адресу в ячейке области данных BIOS 0040:0067 (то есть без перепрограммирования контроллера прерываний).

Таким образом, если вы не используете прерываний, то достаточно установить байт 0fh в CMOS-памяти в 0ah. Предварительно, конечно, вы должны инициализировать ячейку области данных BIOS 0040:0067 значением адреса, по которому необходимо передать управление после сброса. Для программирования CMOS-памяти используются номера портов 070h и 071h. Вначале в порт 070h заносится нужный номер ячейки CMOS-памяти, а затем в порт 071h — новое значение этой ячейки.

;работаем в реальном режиме, готовимся к переходу

;в защищенный режим:

        push    es

        mov     ax,40h

        mov     es,ax

        mov     word ptr es:[67h],offset ret_real

;ret_real — метка в программе, с которой должно

;начаться выполнение программы после сброса

        mov     es:[69h],cs

        mov     al,0fh  ;будем обращаться к ячейке 0fh в CMOS

        out     70h,al

        jmp     $+2     ;чуть задержимся, чтобы аппаратура отработала

;сброс без перепрограммирования контроллера

        mov     al,0ah

        out     71h,al

;переходим в защищенный режим установкой

;бита 0 cr0 в 1 (см. урок 16)

;работаем в защищенном режиме

;готовимся перейти обратно в реальный режим

        mov     al,01fch

        out     64h,al  ;сброс микропроцессора  hlt

;остановка до физического окончания процесса сброса

        ret_real:       ...     ;метка, на которую будет передано

                        ;управление после сброса

См. также: уроки 15, 16, 17

IDIV

(Integer DIVide)

Деление целочисленное со знаком

Назначение: операция деления двух двоичных значений со знаком.

Синтаксис
Алгоритм работы:
Для команды необходимо задание двух операндов — делимого и делителя. Делимое задается неявно, и размер его зависит от размера делителя, местонахождение которого указывается в команде:

• если делитель размером в байт, то делимое должно быть расположено в регистре ax. После операции частное помещается в al, а остаток — в ah;
• если делитель размером в слово, то делимое должно быть расположено в паре регистров dx:ax, причем младшая часть делимого находится в ax. После операции частное помещается в ax, а остаток — в dx;
• если делитель размером в двойное слово, то делимое должно быть расположено в паре регистров edx:eax, причем младшая часть делимого находится в eax. После операции частное помещается в eax, а остаток — в edx;

Остаток всегда имеет знак делимого. Знак частного зависит от состояния знаковых битов (старших разрядов) делимого и делителя.
Состояние флагов после выполнения команды:

Применение:
Команда выполняет целочисленное деление операндов с учетом их знаковых разрядов. Результатом деления являются частное и остаток от деления. При выполнении операции деления возможно возникновение исключительной ситуации: 0 — ошибка деления. Эта ситуация возникает в одном из двух случаев: делитель равен 0 или частное слишком велико для его размещения в регистре eax/ax/al.

;деление слов

        mov     ax,1045 ;делимое

        mov     bx,587  ;делитель

        cwd             ;расширение делимого dx:ax

        idiv    bx      ;частное в ax, остаток в dx

См. также: урок 8, приложение 7 и команду div

IMUL

(Integer MULtiply)

Умножение целочисленное со знаком

Назначение: операция умножения двух целочисленных двоичных значений со знаком.

Синтаксис
Алгоритм работы:
Алгоритм работы команды зависит от используемой формы команды. Форма команды с одним операндом требует явного указания местоположения только одного сомножителя, который может быть расположен в ячейке памяти или регистре. Местоположение второго сомножителя фиксировано и зависит от размера первого сомножителя:

• если операнд, указанный в команде, — байт, то второй сомножитель располагается в al;
• если операнд, указанный в команде, — слово, то второй сомножитель располагается в ax;
• если операнд, указанный в команде, — двойное слово, то второй сомножитель располагается в eax.

Результат умножения для команды с одним операндом также помещается в строго определенное место, определяемое размером сомножителей:

• при умножении байтов результат помещается в ax;
• при умножении слов результат помещается в пару dx:ax;
• при умножении двойных слов результат помещается в пару edx:eax.

Команды с двумя и тремя операндами однозначно определяют расположение результата и сомножителей следующим образом:

• в команде с двумя операндами первый операнд определяет местоположение первого сомножителя. На его место впоследствии будет записан результат. Второй операнд определяет местоположение второго сомножителя;
• в команде с тремя операндами первый операнд определяет местоположение результата, второй операнд — местоположение первого сомножителя, третий операнд может быть непосредственно заданным значением размером в байт, слово или двойное слово.

Состояние флагов после выполнения команды:

Команда imul устанавливает в ноль флаги of и cf, если размер результата соответствует регистру назначения. Если эти флаги отличны от нуля, то это означает, что результат слишком велик для отведенных ему регистром назначения рамок и необходимо указать больший по размеру регистр для успешного завершения данной операции умножения. Конкретными условиями сброса флагов of и cf в ноль являются следующие условия:

• для однооперандной формы команды imul регистры ax/dx/edx являются знаковыми расширениями регистров al/ax/eax;
• для двухоперандной формы команды imul для размещения результата умножения достаточно размерности указанных регистров назначения r16/r32;
• то же для трехоперандной команды умножения.

Применение:
Команда выполняет целочисленное умножение операндов с учетом их знаковых разрядов. Для выполнения этой операции необходимо наличие двух сомножителей. Размещение и задание их местоположения в команде зависит от формы применяемой команды умножения, которая, в свою очередь, определяется моделью микропроцессора. Так, для микропроцессора i8086 возможна только однооперандная форма команды, для последующих моделей микропроцессоров дополнительно можно использовать двух- и трехоперандные формы этой команды.

.486

...

        mov     bx,186

        imul    eax,bx,8

;если результату не хватило размерности операнда1,

;то перейдем на m1, где скорректируем ситуацию:

        jc      m1

См. также: урок 8, приложение 7 и команду mul

IN

(INput operand from port)

Ввод операнда из порта

Назначение: ввод значения из порта ввода-вывода.

Синтаксис
Алгоритм работы:
Передает байт, слово, двойное слово из порта ввода-вывода в один из регистров al/ax/eax. Состояние флагов после выполнения команды: выполнение команды не влияет на флаги.
Состояние флагов после выполнения команды:

Применение:
Команда применяется для прямого управления оборудованием компьютера посредством портов. Номер порта задается вторым операндом в виде непосредственного значения или значения в регистре dx. Непосредственным значением можно задать порт с номером в диапазоне 0-255. При использовании порта с большим номером используется регистр dx. Размер данных определяется размерностью первого операнда и может быть байтом, словом, двойным словом. В качестве примера применения рассмотрим фрагмент обработчика прерывания от клавиатуры 9. Это прерывание вызывается всякий раз при нажатии любой клавиши на клавиатуре. Обработчик этого прерывания должен прочитать скан-код клавиши, подтвердить микропроцессору клавиатуры факт приема скан-кода, преобразовать этот код в соответствии с клавишами-переключателями и поместить преобразованный код в буфер клавиатуры, находящийся в области BIOS. Действия чтения и подтверждения приема скан-кода могут выглядеть, к примеру, так:

        in      al,60h  ;читаем скан-код

        push    ax      ;сохраним его на время

        in      al,61h  ;читаем порт 61h

        or      al,80h  ;старший бит байта из порта 61h в 1

        out     61h,al  ;подтверждаем факт приема скан-кода

        pop     ax

        out     61h,al  ;восстановили байт в порту 61h

См. также: урок 7 и команды out, ins/insb/insw/insd, outs

INC

(INCrement operand by 1)

Увеличить операнд на 1

Назначение: увеличение значения операнда в памяти или регистре на 1.

Синтаксис
Алгоритм работы:
команда увеличивает операнд на единицу.
Состояние флагов после выполнения команды:

Применение:
Команда используется для увеличения значения байта, слова, двойного слова в памяти или регистре на единицу. При этом команда не воздействует на флаг cf.

        inc     ax      ;увеличить значение в ax на 1

См. также: урок 8 и команды dec, add, adc

INS/INSB/INSW/INSD

(Input String Byte/Word/Double word operands)

Ввод строк байтов/слов/двойных слов из порта

Назначение: ввод из порта в память последовательности байт, слов, двойных слов.

Синтаксис
Алгоритм работы:

• передать данные из порта ввода-вывода, номер которого загружен в регистр dx, в память по адресу es:edi/di;
• в зависимости от состояния флага df изменить значение регистров edi/di:
• если df=0, то увеличить содержимое этих регистров на длину структурного элемента последовательности;
• если df=1, то уменьшить содержимое этих регистров на длину структурного элемента последовательности;
• при наличии префикса выполнить определяемые им действия (см. команду rep).

Состояние флагов после выполнения команды:

Применение:
Команда вводит данные из порта ввода-вывода, номер которого загружен в регистр dx, в память по адресу es:edi/di. Сегментная составляющая адреса должна быть обязательно в регистре es. Замена сегментного регистра недопустима. Непосредственное задание порта в команде также недопустимо - для этого используется регистр dx. Размеры вводимых элементов зависят от применяемой команды. Команда ins может работать с элементами размером в байт, слово, двойное слово. В качестве операндов в команде указывается символическое имя ячейки памяти, в которую вводятся элементы из порта ввода-вывода. Реально это символическое имя используется лишь для получения типа элемента последовательности, а его адрес должен быть предварительно загружен в пару регистров es:edi/di. Транслятор, обработав команду ins и выяснив тип операнда, генерирует одну из машинных команд insb, insw или insd. Машинного аналога для команды ins нет. Для того чтобы эти команды можно было использовать для ввода последовательности элементов, имеющих размерность байт, слово, двойное слово, необходимо использовать префикс rep. Префикс rep заставляет циклически выполняться команду ввода до тех пор, пока содержимое регистра ecx/cx не станет равным нулю.

.286

;ввести 10 байт из порта 300h (номер порта bgr условно)

;в цепочку байт в памяти по адресу

str_10  db      10 dup(0)

adr_str dd      str_10

        les     di,adr_str

        mov     dx,300h

rep     insb

...

См. также: уроки 2, 11 и команды cmps/cmpsb/cmpsw/cmpsd, lods/lodsb/lodsw/lodsd, movs/movsb/movsw/movsd, outs, scas/scasb/scasw/scasd, stos/stosb/stosw/stosd, rep/repe/repz/repne/repnz

INT

(INTerrupt)

Вызов подпрограммы обслуживания прерывания

Назначение: вызов подпрограммы обслуживания прерывания с номером прерывания, заданным операндом команды.

Синтаксис
Алгоритм работы:

• записать в стек регистр флагов eflags/flags и адрес возврата. При записи адреса возврата вначале записывается содержимое сегментного регистра cs, затем содержимое указателя команд eip/ip;
• сбросить в ноль флаги if и tf;
• передать управление на программу обработки прерывания с указанным номером. Механизм передачи управления зависит от режима работы микропроцессора (см. уроки 15 и 17).

Состояние флагов после выполнения команды:

Применение:
Как видно из синтаксиса, существуют две формы этой команды:

• int 3 — имеет свой индивидуальный код операции 0cch и занимает один байт. Это обстоятельство делает ее очень удобной для использования в различных программных отладчиках для установки точек прерывания путем подмены первого байта любой команды. Микропроцессор, встречая в последовательности команд команду с кодом операции 0cch, вызывает программу обработки прерывания с номером вектора 3, которая служит для связи с программным отладчиком.
• Вторая форма команды занимает два байта, имеет код операции 0cdh и позволяет инициировать вызов подпрограммы обработки прерывания с номером вектора в диапазоне 0–255. Особенности передачи управления, как было отмечено, зависят от режима работы микропроцессора.

;вызов обработчика аппаратного прерывания 08h из программы:

        int     08h

См. также: уроки 15, 17 и команды into, iret/iretd

INTO

(INTerrupt if Overflow)

Прерывание, если переполнение

Назначение: инициирование прерывания с номером 4, если установлен флаг of.

Синтаксис
Алгоритм работы:
Проанализировать состояние флага of:

• если of=0, то никаких действий производить не нужно — передать управление на следующую команду;
• если of=1, то дальнейшие действия, как при команде int, то есть:
• записать в стек регистр флагов eflags/flags и адрес возврата. При записи адреса возврата вначале записывается содержимое сегментного регистра cs, затем содержимое указателя команд eip/ip;
• сбросить в ноль флаги if и tf;
• передать управление на программу обработки прерывания с данным номером. Механизм передачи зависит от режима работы микропроцессора (см. уроки 15 и 17).

Состояние флагов после выполнения команды:

Применение:
Свойство этой команды инициировать вызов подпрограммы обработки прерывания с номером вектора 4 определяет варианты ее применения. Если предыдущая команда в программе может в результате своей работы установить флаг переполнения of (к примеру, арифметические команды), то для обнаружения и обработки такой ситуации можно использовать команду into. Особенности передачи управления и обработки (корректировки) результата зависят от режима работы микропроцессора.

.486

...

        mov     bx,186

        imul    eax,bx,8

;если результату не хватило размерности операнда1,

;то of установится в 1

;исправим ситуацию в обработчике прерывания 3

        into

См. также: уроки 8, 15, 17 и команды int, iret/iretd, imul

IRET/IRETD

(Interrupt RETurn)

Возврат из прерывания

Назначение: используется в той точке программы обработки прерывания, откуда необходимо вернуть управление прерванной программе.

Синтаксис
Алгоритм работы:
Работа команды зависит от режима работы микропроцесссора:

• в реальном режиме команда iret последовательно извлекает из стека и затем восстанавливает в микропроцессоре содержимое следующих регистров: eip/ip, cs, eflags/flags. Далее прерванная программа продолжается с точки прерывания;
• в защищенном режиме действия команды зависят от состояния флага NT (вложенной задачи) в регистре флагов:
• если NT=0, то производятся действия по возврату управления прерванной программе, при этом характер этих действий зависит от соотношения уровней привилегированности прерванной программы и программы обработки прерывания;
• в случае NT=1 производятся действия по переключению задач.

Состояние флагов после выполнения команды:

Применение:
Команду iret необходимо применять для восстановления сохраненных командой int регистров флагов, указателя команд и сегментного регистра кода. Число этих команд в программе обработки прерывания должно соответствовать количеству точек выхода из нее. Команда iretd используется в старших моделях микропроцессоров для извлечения из стека и восстановления 32-битных регистров.

my_int1c        proc

;программа обработки прерывания 1Ch

...

        iret

        endp

См. также: уроки 15, 17 и команды int, into

JCC
JCXZ/JECXZ

(Jump if condition)

(Jump if CX=Zero/ Jump if ECX=Zero)

Переход, если выполнено условие

Переход, если CX/ECX равен нулю

Назначение: переход внутри текущего сегмента команд в зависимости от некоторого условия.

Синтаксис
Алгоритм работы команд (кроме jcxz/jecxz):
Проверка состояния флагов в зависимости от кода операции (оно отражает проверяемое условие):

• если проверяемое условие истинно, то перейти к ячейке, обозначенной операндом;
• если проверяемое условие ложно, то передать управление следующей команде.

Алгоритм работы команды jcxz/jecxz:
Проверка условия равенства нулю содержимого регистра ecx/cx:

• если проверяемое условие истинно, то есть содержимое ecx/cx равно 0, то перейти к ячейке, обозначенной операндом метка;
• если проверяемое условие ложно, то есть содержимое ecx/cx не равно 0, то передать управление следующей за jcxz/jecxz команде программы.

Состояние флагов после выполнения команды:

Применение (кроме jcxz/jecxz):
Команды условного перехода удобно применять для проверки различных условий, возникающих в ходе выполнения программы. Как известно, многие команды формируют признаки результатов своей работы в регистре eflags/flags. Это обстоятельство и используется командами условного перехода для работы. Ниже приведены перечень команд условного перехода, анализируемые ими флаги и соответствующие им логические условия перехода.

Логические условия "больше" и "меньше" относятся к сравнениям целочисленных значений со знаком, а "выше и "ниже" — к сравнениям целочисленных значений без знака. Если внимательно посмотреть, то у многих команд можно заметить одинаковые значения флагов для перехода. Это объясняется наличием нескольких ситуаций, которые могут вызвать одинаковое состояние флагов. В этом случае с целью удобства ассемблер допускает несколько различных мнемонических обозначений одной и той же машинной команды условного перехода. Эти команды ассемблера по действию абсолютно равнозначны, так как это одна и та же машинная команда. Изначально в микропроцессоре i8086 команды условного перехода могли осуществлять только короткие переходы в пределах -128...+127 байт, считая от следующей команды. Начиная с микропроцессора i386, эти команды уже могли выполнять любые переходы в пределах текущего сегмента команд. Это стало возможным за счет введения в систему команд микропроцессора дополнительных машинных команд. Для реализации межсегментных переходов необходимо комбинировать команды условного перехода и команду безусловного перехода jmp. При этом можно воспользоваться тем, что практически все команды условного перехода парные, то есть имеют команды, проверяющие обратные условия.
Применение jcxz/jecxz:

Команду jcxz/jecxz удобно использовать со всеми командами, использующими регистр ecx/cx для своей работы. Это команды организации цикла и цепочечные команды. Очень важно отметить то, что команда jcxz/jecxz, в отличие от других команд перехода, может выполнять только близкие переходы в пределах -128...+127 байт, считая от следующей команды. Поэтому для нее особенно актуальна проблема передачи управления далее чем в указанном диапазоне. Для этого можно привлечь команду безусловного перехода jmp. Например, команду jcxz/jecxz можно использовать для предварительной проверки счетчика цикла в регистре cx для обхода цикла, если его счетчик нулевой.

...

        jcxz    m1      ;обойти цикл, если cx=0

cycl:

;некоторый цикл

        loop    cycl

m1:     ...

См. также: уроки 10, 11 и команду jmp

JMP

(JuMP)

Переход безусловный

Назначение: используется в программе для организации безусловного перехода как внутри текущего сегмента команд, так и за его пределы. При определенных условиях в защищенном режиме работы команда jmp может использоваться для переключения задач.

Синтаксис
Алгоритм работы:
Команда jmp в зависимости от типа своего операнда изменяет содержимое либо только одного регистра eip, либо обоих регистров cs и eip:

• если операнд в команде jmp — метка в текущем сегменте команд (a8, 16, 32), то ассемблер формирует машинную команду, операнд которой является значением со знаком, являющимся смещением перехода относительно следующей за jmp команды. При этом виде перехода изменяется только регистр eip/ip;
• если операнд в команде jmp — символический идентификатор ячейки памяти (m16, 32, 48), то ассемблер предполагает, что в ней находится адрес, по которому необходимо передать управление. Этот адрес может быть трех видов:
• значением абсолютного смещения метки перехода относительно начала сегмента кода. Размер этого смещения может быть 16 или 32 бит в зависимости от режима адресации;
• дальним указателем на метку перехода в реальном и защищенном режимах, содержащим два компонента адреса — сегментный и смещение. Размеры этих компонентов также зависят от установленного режима адресации (use16 или use32). Если текущим режимом является use16, то адрес сегмента и смещение занимают по 16 бит, причем смещение располагается в младшем слове двойного слова, отводимого под этот полный адрес метки перехода. Если текущим режимом является use32, то адрес сегмента и смещение занимают, соответственно, 16 и 32 бит, — в младшем двойном слове находится смещение, в старшем — адрес сегмента;
• адресом в одном из 16 или 32-разрядных регистров — этот адрес представляет собой абсолютное смещение метки, на которую необходимо передать управление, относительно начала сегмента команд.

Для понимания различий механизмов перехода в реальном и защищенном режимах нужно помнить следующее. В реальном режиме микропроцессор просто изменяет cs и eip/ip в соответствии с содержимым указателя в памяти. В защищенном режиме микропроцессор предварительно анализирует байт прав доступа AR в дескрипторе, номер которого определяется по содержимому сегментной части указателя. В зависимости от состояния байта AR микропроцессор выполняет либо переход, либо переключение задач.
Состояние флагов после выполнения команды (за исключением случая переключения задач):

Применение:
Команду jmp применяют для осуществления ближних и дальних безусловных переходов без сохранения контекста точки перехода.
См. также: урок 10, команды call, jcc

LAHF

(Load AH register from register Flags)

Загрузка регистра AH флагами из регистра eFlags/Flags

Назначение: извлечение содержимого младшего байта регистра eflags/flags, в котором содержатся пять флагов: cf, pf, af, zf и sf.

Синтаксис
Алгоритм работы:
команда загружает регистр ah содержимым младшего байта регистра eflags/flags. Состояние флагов после выполнения команды:

Применение:
Из-за того, что регистр флагов непосредственно недоступен, команду lahf можно применять для анализа и последующего изменения командой sahf состояния некоторых флагов регистра eflags/flags.

;сбросить в ноль флаг cf

        lahf

        and     ah,11111110b

        sahf

См. также: команду sahf

LDS/LES/LFS/LGS/LSS

(Load pointer into ds/es/fs/gs/ss segment register)

Загрузка сегментного регистра ds/es/fs/gs/ss указателем из памяти

Назначение: получение полного указателя в виде сегментной составляющей и смещения.

Синтаксис
Алгоритм работы:
Алгоритм работы команды зависит от действующего режима адресации (use16 или use32):

• если use16, то загрузить первые два байта из ячейки памяти источник в 16-разрядный регистр, указанный операндом приемник. Следующие два байта в области источник должны содержать сегментную составляющую некоторого адреса; они загружаются в регистр ds/es/fs/gs/ss;
• если use32, то загрузить первые четыре байта из ячейки памяти источник в 32-разрядный регистр, указанный операндом приемник. Следующие два байта в области источник должны содержать сегментную составляющую, или селектор, некоторого адреса; они загружаются в регистр ds/es/fs/gs/ss.

Состояние флагов после выполнения команды:

Применение:
Таким образом, с помощью данных команд в паре регистров ds/es/fs/gs/ss и приемник оказывается полный адрес некоторой ячейки памяти. Это обстоятельство можно использовать, к примеру, при работе с цепочечными командами, где существуют жесткие соглашения на размещение адресов обрабатываемых строк. Помните, что любая загрузка сегментного регистра приводит к обновлению соответствующего теневого регистра (см. урок 16). Смотрите также описание команды cmps с примером использования.
См. также: уроки 5, 7, 11, команды lea и операторы ассемблера seg и offset

LEA

(Load Effective Address)

Загрузка эффективного адреса

Назначение: получение эффективного адреса (смещения) источника.

Синтаксис
Алгоритм работы:
алгоритм работы команды зависит от действующего режима адресации (use16 или use32):

• если use16, то в регистр приемник загружается 16-битное значение смещения операнда источник;
• если use32, то в регистр приемник загружается 32-битное значение смещения операнда источник.

Состояние флагов после выполнения команды:

Применение:
Данная команда является альтернативой оператору ассемблера offset. В отличие от offset команда lea допускает индексацию операнда, что позволяет более гибко организовать адресацию операндов.

;загрузить в регистр bx адрес пятого

элемента массива mas

.data

mas     db      10 dup (0)

.code

...

        mov     di,4

        lea     bx,mas[di]

;или

        lea     bx,mas[4]

;или

        lea     bx,mas+4

См. также: уроки 5, 7, 11 и команды lea, lds, les, lss, lgs, lfs, операторы ассемблера seg и offset

LEAVE

(LEAVE from procedure)

Выход из процедуры

Назначение: удаление из стека области локальных (динамических) переменных, выделенной командой enter.

Синтаксис
Алгоритм работы:
команда выполняет обратные команде enter действия:

• содержимое ebp/bp копируется в esp/sp, тем самым восстанавливается значение esp/sp, которое было до вызова данной процедуры. С другой стороны, восстановление старого значения esp/sp означает освобождение пространства в стеке, отведенного для завершающейся процедуры (локальные переменные процедуры уничтожаются);
• из стека восстанавливается содержимое ebp/bp, которое было до входа в процедуру. После этого действия значение esp/sp также становится таким, каким оно было до входа в процедуру.

В результате этих двух действий также восстанавливается кадр стека, если он был, вызывающей программы.
Состояние флагов после выполнения команды:

Применение:
Команда leave не имеет операндов и выполняет обратные команде enter действия. Эта команда должна находиться непосредственно перед командой ret, которая в зависимости от соглашений конкретного языка по вызову процедур удаляет или не удаляет аргументы из стека (см. урок 14).

.286

proc1   proc

        enter   16,0

...

        leave

        ret

proc1   endp

См. также: урок 14 и команды enter, ret/retf

LGDT

(Load Global Descriptor Table)

Загрузка регистра глобальной дескрипторной таблицы

Назначение: загрузка регистра gdtr значениями базового адреса и размера глобальной дескрипторной таблицы GDT.

Синтаксис
Алгоритм работы:
команда выполняет загрузку 16 бит размера и 32 бит значения базового адреса начала таблицы GDT в памяти в системный регистр gdtr. Эта загрузка производится в соответствии с форматом этого регистра (см. урок 16). Состояние флагов после выполнения команды:

Применение:
Команду lgdt применяют при подготовке к переходу в защищенный режим для загрузки системного регистра gdtr. В качестве операнда в команде указывается адрес области в формате 16+32. Младшее слово области — размер GDT, двойное слово по старшему адресу — значение базового адреса начала этой таблицы. Данные два компонента должны быть сформированы в памяти заранее.

.286

;структура для описания псевдодескриптора gdtr

point   STRUC

lim     dw      0

adr     dd      0

 ENDS

.data

point_gdt       point   

.code

...

;загружаем gdtr

        xor     eax,eax

        mov     ax,gdt_seg

        shl     eax,4

        mov     point_gdt.adr,eax

        lgdt    point_gdt

...

См. также: уроки 16, 17 и команду sgdt

LIDT

(Load Interrupt Descriptor Table)

Загрузка регистра глобальной дескрипторной таблицы

Назначение: загрузка регистра idtr значениями базового адреса и размера глобальной дескрипторной таблицы IDT.

Синтаксис
Алгоритм работы:
Команда lidt аналогична lgdt, но для дескрипторной таблицы прерываний IDT (см. урок 17).
Состояние флагов после выполнения команды:

Применение:
Команду lidt применяют при подготовке к переходу в защищенный режим для загрузки системного регистра idtr. В качестве операнда в команде указывается адрес области в формате 16+32. Младшее слово области — размер IDT, двойное слово по старшему адресу — значение базового адреса начала этой таблицы. Два данных компонента должны быть сформированы в памяти заранее.

.386

;структура для описания псевдодескрипторов gdtr и idtr

point   STRUC

lim     dw      0

adr     dd      0

 ENDS

.data

point_idt       point   

.code

...

;загружаем idtr

        xor     eax,eax

        mov     ax,IDT_SEG

        shl     eax,4

        mov     point_idt.adr,eax

        lidt    point_idt

...

См. также: урок 17 и команду sidt

LODS/LODSB/LODSW/LODSD

(LOad String Byte/Word/Double word operands)

Загрузка строки байтов/слов/двойных слов

Назначение: загрузка элемента из последовательности (цепочки) в регистр-аккумулятор al/ax/eax.

Синтаксис
Алгоритм работы:

• загрузить элемент из ячейки памяти, адресуемой парой ds:esi/si, в регистр al/ax/eax. Размер элемента определяется неявно (для команды lods) или явно в соответствии с применяемой командой (для команд lodsb, lodsw, lodsd);
• изменить значение регистра si на величину, равную длине элемента цепочки. Знак этой величины зависит от состояния флага df:
• df=0 — значение положительное, то есть просмотр от начала цепочки к ее концу;
• df=1 — значение отрицательное, то есть просмотр от конца цепочки к ее началу.

Состояние флагов после выполнения команды:

Применение:
Команды извлекают элемент из ячейки памяти в один из регистров. Перед командой lods можно указать префикс повторения rep, но в этом нет особого смысла, так как обычно эту команду используют в некотором цикле для просмотра некоторой цепочки с элементами фиксированного размера.

str     db      ...

...

        cld

        lea     si,str

        lodsb   ;загрузить первый байт из str в al

См. также: урок 11 и команды ins/insb/insw/insd, cmps/cmpsb/cmpsw/cmpsd, movs/movsb/movsw/movsd, outs, scas/scasb/scasw/scasd, stos/stosb/stosw/stosd, rep/repe/repz/repne/repnz

LOOP

(LOOP control by register cx)

Управление циклом по cx

Назначение: организация цикла со счетчиком в регистре cx.

Синтаксис
Алгоритм работы:

• выполнить декремент содержимого регистра ecx/cx;
• анализ регистра ecx/cx:
• если ecx/cx=0, передать управление следующей за loop команде;
• если ecx/cx=1, передать управление команде, метка которой указана в качестве операнда loop.

Состояние флагов после выполнения команды:

Применение:
Команду loop применяют для организации цикла со счетчиком. Количество повторений цикла задается значением в регистре ecx/cx перед входом в последовательность команд, составляющих тело цикла. Помните о двух важных моментах:

• для предотвращения выполнения цикла при нулевом ecx/cx используйте команду jecxz/jcxz. Если этого не сделать, то при изначально нулевом ecx/cx цикл повторится 4 294 967 295/65 536 раз;
• смещение метки, являющейся операндом loop, не должно выходить из диапазона -128...+127 байт. Это смещение, как и в командах условного перехода, является относительным от значения счетчика адреса следующей за loop команды.

        mov     cx,10

...

        jcxz    m1

cycl:

;тело цикла

        loop    cycl

m1:

См. также: урок 10 и команды jecxz/jcxz, loope/loopz, loopne/loopnz

LOOPE/LOOPZ
LOOPNE/LOOPNZ

(LOOP control by register cx not equal 0 and ZF=1)

(LOOP control by register cx not equal 0 and ZF=0)

Управление циклом по cx c учетом значения флага ZF

Назначение: организация цикла со счетчиком в регистре cx с учетом флага zf.

Синтаксис
Алгоритм работы:

• выполнить декремент содержимого регистра ecx/cx;
• проанализировать регистр ecx/cx:
• если ecx/cx=0, передать управление следующей за loopxx команде;
• если ecx/cx=1, передать управление команде, метка которой указана в качестве операнда loopxx;
• анализ флага zf:
• если zf=0, для команд loope/loopz это означает выход из цикла, для команд loopne/loopnz — переход к началу цикла;
• если zf=1, для команд loope/loopz это означает переход к началу цикла, для команд loopne/loopnz — выход из цикла.

Состояние флагов после выполнения команды:

Применение:
Команды loopxx удобно использовать вместе с командами, которыe в результате своей работы меняют значение флага zf. Типичный пример — команда сравнения cmp.

;найти первый пробел в строке символов

str     db      'Найти первый пробел'

str_size=$-str

...

        cld

        mov     cx,str_size

        lea     si,str

cycl:

        lodsb

        cmp     al,' '

        loopne  cycl

        jcxz    m1      ;переход, если пробелов нет

        dec     si      ;в si — адрес пробела в строке str

...

m1

См. также: уроки 8, 10, 11 и команду loop

MOV

(MOVe operand)

Пересылка операнда

Назначение: пересылка данных между регистрами или регистрами и памятью.

Синтаксис
Алгоритм работы:
копирование второго операнда в первый операнд.
Состояние флагов после выполнения команды:

Применение:
Команда mov применяется для различного рода пересылок данных, при этом, несмотря на всю простоту этого действия, необходимо помнить о некоторых ограничениях и особенностях выполнения данной операции:

• направление пересылки в команде mov всегда справа налево, то есть из второго операнда в первый;
• значение второго операнда не изменяется;
• оба операнда не могут быть из памяти (при необходимости можно использовать цепочечную команду movs);
• лишь один из операндов может быть сегментным регистром;
• желательно использовать в качестве одного из операндов регистр al/ax/eax, так как в этом случае TASM генерирует более быструю форму команды mov.

        mov     al,5

        mov     bl,al

        mov     bx,ds

См. также: урок 10 и команды movs, lods/lodsb/lodsw/lodsd, stos/stosb,
stosw/stosd

MOV

(MOVe operand to/from system registers)

Пересылка операнда в системные регистры (или из них)

Назначение: пересылка данных между регистрами или регистрами и памятью.

Синтаксис
Алгоритм работы:
копирование второго операнда в первый.
Состояние флагов после выполнения команды:

Применение:
Команда mov применяется для обмена данными между системными регистрами. Это одна из немногих возможностей доступа к содержимому этих регистров. Данную команду можно использовать только на нулевом уровне привилегий либо в реальном режиме работы микропроцессора.

.286

;переключение микропроцессора в защищенный

режим36:

        mov     eax,cr0

        bts     eax,0

        mov     cr0,eax

См. также: уроки 16, 17 и команды mov, bts

MOVS/MOVSB/MOVSW/MOVSD

(MOVe String Byte/Word/Double word)

Пересылка строк байтов/слов/двойных слов

Назначение: пересылка элементов двух последовательностей (цепочек) в памяти.

Синтаксис
Алгоритм работы:

• выполнить копирование байта, слова или двойного слова из операнда источника в операнд приемник, при этом адреса элементов предварительно должны быть загружены:
• адрес источника — в пару регистров ds:esi/si (ds по умолчанию, допускается замена сегмента);
• адрес приемника — в пару регистров es:edi/di (замена сегмента не допускается);
• в зависимости от состояния флага df изменить значение регистров esi/si и edi/di:
• если df=0, то увеличить содержимое этих регистров на длину структурного элемента последовательности;
• если df=1, то уменьшить содержимое этих регистров на длину структурного элемента последовательности;
• если есть префикс повторения, то выполнить определяемые им действия (см. команду rep).

Состояние флагов после выполнения команды:

Применение:
Команды пересылают элемент из одной ячейки памяти в другую. Размеры пересылаемых элементов зависят от применяемой команды. Команда movs может работать с элементами размером в байт, слово, двойное слово. В качестве операндов в команде указываются идентификаторы последовательностей этих элементов в памяти. Реально эти идентификаторы используются лишь для получения типов элементов последовательностей, а их адреса должны быть предварительно загружены в указанные выше пары регистров. Транслятор, обработав команду movs и выяснив тип операндов, генерирует одну из машинных команд movsb, movsw или movsd. Машинного аналога для команды movs нет. Для адресации операнда приемник обязательно должен использоваться регистр es.
Для того чтобы эти команды можно было использовать для пересылки последовательности элементов, имеющих размерность байт, слово, двойное слово, необходимо использовать префикс rep. Префикс rep заставляет циклически выполняться команды пересылки до тех пор, пока содержимое регистра ecx/cx не станет равным нулю.

str1    db      'str1 копируется в str2'

len_str1=$-str1

a_str1  dd      str1

str2    db      len_str1 dup (' ')

a_str2  dd      str2

...

        mov     cx,len_str1

        lds     si,str1

        les     di,str2

        cld

rep     movsb

См. также: урок 11 и команды cmps/cmpsb/cmpsw/cmpsd, ins/insb/insw/insd, lods/lodsb/lodsw/lodsd, outs, scas/scasb/scasw/scasd, stos/stosb/stosw/stosd, rep/repe/repz/repne/repnz

MOVSX

(MOVe and Sign eXtension)

Пересылка со знаковым расширением

Назначение: преобразование элементов со знаком меньшей размерности в эквивалентные им элементы со знаком большей размерности.

Синтаксис
Алгоритм работы:

• считать содержимое источника;
• записать содержимое операнда источника в операнд приемник, начиная с младших разрядов источника;
• распространить значение знакового разряда источника на свободные старшие разряды операнда назначения.

Состояние флагов после выполнения команды:

Применение:
Команду movsx обычно используют для получения эквивалентного, но большего по размеру операнда со знаком. Это может понадобиться для приведения размера операнда к нужному значению с целью обеспечения работы следующих команд программы:

        mov     al,0ffh

        movsx   bx,al   ;bx=0ffffh

См. также: урок 8 и команды mov, movs, movzx, cbw, cwd, cdq

MOVZX

(MOVe and Zero eXtension)

Пересылка с нулевым расширением

Назначение: преобразование элементов без знака меньшей размерности в эквивалентные им элементы без знака большей размерности.

Синтаксис
Алгоритм работы:

• считать содержимое источника;
• записать содержимое операнда источника в операнд приемник, начиная с его младших разрядов;
• распространить двоичный нуль на свободные старшие разряды операнда назначения.

Состояние флагов после выполнения команды:

Применение:
Команду movzx обычно используют для получения эквивалентного, но большего по размеру операнда без учета знака. Она может быть использована для согласования операндов различной размерности. Но не следует думать, что все эти разнотипные пересылки делает одна машинная команда. На самом деле существует несколько машинных команд, каждая из которых работает со своими размерами операндов. Генерацию же нужной команды обеспечивает транслятор на основе анализа исходного текста программы.

.data

sl      db      ?

.code

...

        mov     al,0ffh

        movzx   bx,al   ;bx=00ffh

...

;или из памяти:

        movzx   eax,byte ptr sl

См. также: урок 8 и команды mov, movs/movsb/
movsw/movsd, movsx, cbw, cwd, cdq

MUL

(MULtiply)

Умножение целочисленное без учета знака

Назначение: операция умножения двух целых чисел без учета знака.

Синтаксис
Алгоритм работы:
Команда выполняет умножение двух операндов без учета знаков. Алгоритм зависит от формата операнда команды и требует явного указания местоположения только одного сомножителя, который может быть расположен в памяти или в регистре. Местоположение второго сомножителя фиксировано и зависит от размера первого сомножителя:

• если операнд, указанный в команде — байт, то второй сомножитель должен располагаться в al;
• если операнд, указанный в команде — слово, то второй сомножитель должен располагаться в ax;
• если операнд, указанный в команде — двойное слово, то второй сомножитель должен располагаться в eax.

Результат умножения помещается также в фиксированное место, определяемое размером сомножителей:

• при умножении байтов результат помещается в ax;
• при умножении слов результат помещается в пару dx:ax;
• при умножении двойных слов результат помещается в пару edx:eax.

Состояние флагов после выполнения команды (если старшая половина результата нулевая):

Состояние флагов после выполнения команды (если старшая половина результата ненулевая):

Применение:
Команда mul выполняет целочисленное умножение операндов без учета их знаковых разрядов. Для этой операции необходимо наличие двух операндов-сомножителей, размещение одного из которых фиксировано, а другого задается операндом в команде. Контролировать размер результата удобно используя флаги cf и of.

mn_1    db      15

mn_2    db      25

...

        mov     al,mn_1

        mul     mn_2

См. также: урок 8 и команду imul

NEG

(NEGate operand)

Изменить знак операнда

Назначение: изменение знака (получение двоичного дополнения) источника.

Синтаксис
Алгоритм работы:

• выполнить вычитание (0 – источник) и поместить результат на место источника;
• если источник=0, то его значение не меняется.

Состояние флагов после выполнения команды (если результат нулевой):

Состояние флагов после выполнения команды (если результат ненулевой):

Применение:
Команда используется для формирования двоичного дополнения операнда в памяти или регистре. Операция двоичного дополнения предполагает инвертирование всех разрядов операнда с последующим сложением операнда с двоичной единицей. Если операнд отрицательный, то операция neg над ним означает получение его модуля.

        mov     al,2

        neg     al      ;al=0feh — число -2 в дополнительном коде

См. также: уроки 6, 8 и команду not

NOP

(No OPeration)

Нет операции

Назначение: пустая команда.

Синтаксис
Алгоритм работы:
не производит никаких действий.
Состояние флагов после выполнения команды:

Применение:
Команда nop, занимая один байт, может использоваться для резервирования места в сегменте кода или организации программной задержки. В качестве иллюстрации можно обратиться к примеру, приведенному в описании команды hlt. В этом примере команду nop можно использовать вместо jmp $+2. Назначение jmp $+2 в этом фрагменте — задержка для синхронизации работы микропроцессора и аппаратуры компьютера.

NOT

(NOT operand)

Инвертирование операнда

Назначение: инвертирование всех битов операнда источник.

Синтаксис
Алгоритм работы:
инвертировать все биты операнда источника: из 1 в 0, из 0 в 1.
Состояние флагов после выполнения команды:

Применение:
Команду not можно использовать для изменения байта, выполняющего роль некоторого флага, с целью отслеживания некоторых логических условий в программе. Но такой способ не оптимален, эту ситуацию мы обсуждали в книге на уроках 9 и 12.

flag    db      0ffh ;значение флага — истина

...

cycl:

...

        cmp     flag,0

        je      m1

...

m1:     not     flag    ;установить флаг в истину

См. также: уроки 9, 12 и команду neg

OR

(logical OR)

Логическое включающее ИЛИ

Назначение: операция логического ИЛИ над битами операнда назначения.

Синтаксис
Алгоритм работы:

• выполнить операцию логического ИЛИ над битами операнда назначения, используя в качестве маски второй операнд — маска. При этом бит результата равен 0, если соответствующие биты операндов маска и назначения равны 0, в противном случае бит равен 1;
• записать результат операции в источник (операнд маска остается неизменным);
• установить флаги.

Состояние флагов после выполнения команды:

Применение:
Команду or можно использовать для работы с операндами на уровне битов. Типичное использование команды — установка определенных разрядов первого операнда в единицу.

        mov     al,01h

        or      bl,al   ;установить нулевой бит в 1

См. также: урок 9 и команды and, xor, not

OUT

(OUT operand to port)

Вывод операнда в порт

Назначение: вывод значения в порт ввода-вывода.

Синтаксис
Алгоритм работы:
Передать байт, слово, двойное слово из регистра al/ax/eax в порт, номер которого определяется первым операндом.
Состояние флагов после выполнения команды:

Применение:
Команда применяется для прямого управления оборудованием компьютера посредством портов. Номер порта задается первым операндом в виде непосредственного значения или значения в регистре dx. Непосредственным значением можно задать порт с номером в диапазоне 0...255. Для указания порта с большим номером используется регистр dx. Размер данных определяется размерностью второго операнда и может быть байтом, словом или двойным словом.

        out     64h,al

См. также: уроки 2, 7, 16, 17 и команды in, ins/insb/insw/insd, outs

OUTS/OUTSB/OUTSW/OUTSD

(OUTput Byte/Word/Double word String to port)

Вывод строки байтов/слов/двойных слов в порт

Назначение: вывод в порт из памяти последовательности байт, слов, двойных слов.

Синтаксис
Алгоритм работы:

• передать данные в порт ввода-вывода, номер которого загружен в регистр dx, из ячейки памяти по адресу ds:esi/si;
• в зависимости от состояния флага df изменить значение регистров esi/si:
• если df=0, то увеличить содержимое этих регистров на длину структурного элемента последовательности;
• если df=1, то уменьшить содержимое этих регистров на длину структурного элемента последовательности;
• при наличии префикса выполнить определяемые им deiqrbh (см. команду rep/repe/repz/repne/repnz).

Состояние флагов после выполнения команды:

Применение:
Команда выводит данные в порт ввода-вывода, номер которого загружен в регистр dx, из ячейки памяти по адресу ds:esi/si (допускается замена сегмента). Недопустимо задание номера порта в команде в виде непосредственного операнда — для этого используется регистр dx. Размеры вводимых элементов зависят от применяемой команды. Команда outs может работать с элементами размером в байт, слово или двойное слово. В качестве операнда в команде указывается символическое имя ячейки памяти, из которой элемент выводится в порт ввода-вывода. Реально символическое имя используется лишь для получения типа элемента последовательности, а ее адрес должен быть предварительно загружен в пару регистров ds:esi/si. Транслятор, обработав команду outs и выяснив тип операндов, генерирует одну из машинных команд outsb, outsw или outsd. Машинного аналога для команды outs нет.
Для того чтобы эти команды можно было использовать для вывода в порт последовательности элементов, имеющих размерность байт, слово или двойное слово, необходимо использовать префикс rep. Он заставляет циклически выполняться команду вывода в порт до тех пор, пока содержимое регистра ecx/cx не станет равным нулю.

.286

;вывести последовательность 10 байт в порт 300h

;(номер порта взят условно)

str_10  db      10 dup(0)

adr_str dd      str_10

        lds     si,adr_str

        mov     dx,300h

rep     outsb

См. также: уроки 2, 7, 11 и команды cmps/cmpsb/cmpsw/cmpsd, lods/lodsb/lodsw/lodsd, movs/movsb/movsw/movsd, ins/insb/insw/insd, scas/scasb/scasw/scasd, stos/stosb/stosw/stosd, rep/repe/repz/repne/repnz

POP

(POP operand from the stack)

Извлечение операнда из стека

Назначение: извлечение слова или двойного слова из стека.

Синтаксис
Алгоритм работы:
Алгоритм работы команды зависит от установленного атрибута размера адреса — use16 или use32:

• загрузить в приемник содержимое вершины стека (адресуется парой ss:esp/sp);
• увеличить содержимое esp/sp на 4 (2 байта) для use32 (соответственно для use16).

Состояние флагов после выполнения команды:

Применение:
Команда применяется для восстановления содержимого вершины стека в регистр, ячейку памяти или сегментный регистр. Заметим, что недопустимо восстановление значения в сегментный регистр cs.

my_proc proc    near

        push    ax

        push    bx

;тело процедуры, в которой изменяется содержимое

;регистров ax и bx

...

        pop     bx

        pop     ax

        ret

        endp

См. также: уроки 7, 10, 14, 15, 16, 17 и команды popa, popad, popf, popfd, push, pusha, pushad, pushf, pushfd

POPA

(POP All general registers from the stack)

Извлечение всех регистров общего назначения из стека

Назначение: извлечение из стека регистров общего назначения di, si, bp, sp, bx, dx, cx, ax.

Синтаксис
Алгоритм работы:

• извлечь из стека последовательно значения и загрузить ими регистры общего назначения di, si, bp, sp, bx, dx, cx, ax. Содержимое di восстанавливается первым. Содержимое sp извлекается, но не восстанавливается;
• увеличить значение указателя стека esp/sp на 16.

Состояние флагов после выполнения команды:

Применение:
Команда popa по принципу работы является обратной команде pusha и используется для восстановления содержимого всех регистров общего назначения значениями из стека. Эту команду можно использовать в процедурах и программах обработки прерываний для восстановления регистров общего назначения прерванной программы.

.386

my_proc proc    near

        pusha

;тело процедуры, в которой изменяется

;содержимое регистров общего назначения

...

        popa

        ret

        endp

См. также: уроки 7, 10, 14, 15, 16, 17 и команды pop, popad, popf, popfd, push, pusha, pushad, pushf, pushfd

POPAD

(POP All general Double word registers from the stack)

Извлечение всех 32-разрядных регистров общего назначения из стека

Назначение: извлечение из стека регистров общего назначения edi, esi, ebp, esp, ebx, edx, ecx, eax.

Синтаксис
Алгоритм работы:

• извлечь из стека последовательно значения и загрузить ими 32-разрядные регистры общего назначения edi, esi, ebp, esp, ebx, edx, ecx, eax. Содержимое edi восстанавливается первым. Содержимое esp извлекается но не восстанавливается;
• увеличить значение указателя стека esp на 32.

Состояние флагов после выполнения команды: